cartographer/flake.nix

{
  description = "A TUI for the Canvas LMS.";

  inputs = {
    nixpkgs.url = "github:NixOS/nixpkgs/nixos-unstable";
    flake-parts.url = "github:hercules-ci/flake-parts";
    fenix = {
      url = "github:nix-community/fenix";
      inputs.nixpkgs.follows = "nixpkgs";
    };
    naersk.url = "github:nix-community/naersk";
  };

  outputs =
    inputs@{
      flake-parts,
      fenix,
      naersk,
      ...
    }:
    flake-parts.lib.mkFlake { inherit inputs; } {
      systems = [
        "aarch64-linux"
        "x86_64-linux"
        "aarch64-darwin"
        "x86_64-darwin"
      ];
      perSystem =
        { system, pkgs, ... }:
        let
          naersk' = pkgs.callPackage naersk { };
          defaultBuildOpts = {
            cargo = fenix.packages.${system}.stable.cargo;
            rustc = fenix.packages.${system}.stable.rustc;
            src = ./.;

            nativeBuildInputs = with pkgs; [ pkg-config ];
            buildInputs = with pkgs; [ openssl ];

            mode = "build";
          };
        in
        {
          devShells.default = pkgs.mkShell {
            buildInputs = with pkgs; [
              pkg-config
              openssl
              fenix.packages.${system}.stable.completeToolchain
              cargo-audit
            ];
          };
          packages = {
            default = naersk'.buildPackage defaultBuildOpts;
            test = naersk'.buildPackage (
              defaultBuildOpts
              // {
                mode = "test";
              }
            );
          };
        };
    };
}