feat: add hyprland-qtutils

hm/modules/linux/desktop-environment/hyprland/default.nix

@@ -49,6 +49,7 @@ in
         libsForQt5.qt5ct
         papirus-icon-theme
         libsForQt5.qt5ct
+        hyprland-qtutils
       ]
       ++ (lib.optionals (!osConfig.liminalOS.theming.enable) [
         pkgs.bibata-cursors

pkgs/by-name/hyprland-qtutils/default.nix

@@ -0,0 +1,49 @@
+{
+  lib,
+  gcc14Stdenv,
+  fetchFromGitHub,
+  cmake,
+  pkg-config,
+  hyprutils,
+  pciutils,
+  qt6,
+}:
+let
+  inherit (lib.strings) makeBinPath;
+in
+gcc14Stdenv.mkDerivation (finalAttrs: {
+  pname = "hyprland-qtutils";
+  version = "0.1.1";
+
+  src = fetchFromGitHub {
+    owner = "hyprwm";
+    repo = "hyprland-qtutils";
+    tag = "v${finalAttrs.version}";
+    hash = "sha256-Zp2cQOo1D7WH7ml5nV7mLyto0l19gTaWnbDb6zty1Qs=";
+  };
+
+  nativeBuildInputs = [
+    cmake
+    pkg-config
+    qt6.wrapQtAppsHook
+  ];
+
+  buildInputs = [
+    hyprutils
+    qt6.qtbase
+    qt6.qtsvg
+    qt6.qtwayland
+  ];
+
+  preFixup = ''
+    qtWrapperArgs+=(--prefix PATH : "${makeBinPath [ pciutils ]}")
+  '';
+
+  meta = {
+    description = "Hyprland QT/qml utility apps";
+    homepage = "https://github.com/hyprwm/hyprland-qtutils";
+    license = lib.licenses.bsd3;
+    maintainers = [ lib.maintainers.fufexan ];
+    platforms = lib.platforms.linux;
+  };
+})

pkgs/default.nix

@@ -4,4 +4,5 @@ let
 in
 final: prev: {
   modrinth-app = callPackage ./by-name/modrinth-app { };
+  hyprland-qtutils = callPackage ./by-name/hyprland-qtutils { };
 }